Impact Calculation Tool code description

This page provides the detailed description of the calculation code in the key parameters of the Impact calculation tool (ICT) -model.

Population in time, child

Parameter identifier: Pop_in_time_child

Population of 0-4 year-olds is projected in one year age and follow-up time intervals for 100 years from the assessment start year onwards, after which the population in the beginning of each 5-year follow-up period is determined. Population of 0-4 year-olds is projected separately in 1-year age and time intervals because mortality risk can vary drastically within the 0-4 age group.

var k: Birth_rate[Fu_year=Year_lt];
k:= if k = null then k[@Year_lt=Followup_time] else k;
var a:= if @Year_lt = 1 then population else (if @age1=1 then k else 0);
a:= a[age1=age_child];
var j:= sum(Mort_rate_scenarios,Mort_endpoint)[age1=age_child];
j:=if Mort_effect = 'Acute' then j[Exposure='BAU'] else j;
j:= if Exp_year_class = 'Yes' then 
(j:=j[Fu_period=period_lt];
j:= if j = null then j[Period_lt=max(Fu_period)] else j;
j:= Si_pi1(j, 5, Period_lt, Year_lt, Year_help)*5)
else j;
j:= if j < 0 then 0 else j;
j:= if j > 2 then 2 else j;
j:= (2-j)/(2+j);
var x:= 1;
while x<= min([size(age_child),size(Year_lt)]) do (
var b:= a*j;
b:= b[@age_child=@age_child-1, @Year_lt=@Year_lt-1];
a:= if b=null then a else b;
x:= x+1);
sum(if Year_lt = period_vs_year then a else 0,Year_lt)

Code description line by line:

1-2: Annual birth rate for 100 year time period starting from the assessment start year and based on the birth rate input data. If the assessment follow-up time < 100 years, the birth rate in the last follow-up year applies for the rest of the 100 year time period.

3-4: The population table for 0-4 year olds for which the projection is based on (age*follow-up year array). Population for all 0-4 year olds in the first year is based on the population input data and the population for 0 year olds in the rest of the follow-up years on the birth rate data.

5: Calculation of the annual total mortality rate (1-year age interval).

6: If mortality effects are defined to be of acute nature (i.e. ERF represents impact on daily instead of annual mortality), the population is projected only based on the total mortality risk in the BAU scenario.

7-11: If exposure is defined to change in the course of the assessment follow-up period, the exposure in one year time intervals based on the exposure input data given in 5-year time intervals. If the assessment follow-up period is < 100 years, the exposure level defined for the last follow-up 5-year period applies for the rest of the 100 years.

12-13: Total mortality rate is limited to be between 0 and 2.

14: Calculation of the annual survival rate.

15-20: The child population is projected through the 100 year time period. Population at a given 1-year age group and year is multiplied with the annual survival rate for that age. The result is the population of the next 1-year age group in the following year.

21: Population in the beginning of each 5-year follow-up period is derived from the annual projection.

Population in time, beginning of time step

Parameter identifier: Pop_in_time_beg

Population is projected in 5-year age and calendar year intervals for 100 years from the assessment start year onwards. The resulting table gives the population in the beginning of each 5-year time step.

var a:= sum(if floor(age1/5)+1 = @age_cat then population else 0, age1);
a:= if @age_cat=1 then sum(pop_in_time_child, age_child) else (if @period_lt = 1 then a else 0);
var j:= sum(Mort_rate_scenarios,Mort_endpoint);
j:=if Mort_effect = 'Acute' then j[Exposure='BAU'] else j;
j:= if Exp_year_class = 'Yes' then
(j:=j[Fu_period=period_lt];
j:= if j = null then j[Period_lt=max(Fu_period)] else j)
else j;
j:= if j < 0 then 0 else j;
j:= if j > 2 then 2 else j;
j:= (2-j)/(2+j);
j:= sum(if floor(age1/5)+1 = @age_cat then j else 0 , age1)/5;
var m:=j[@age_cat=@age_cat+1];
m:= if m=null then 0 else m;
var n:=((j^5)+(j^4*m)+(j^3*m^2)+(j^2*m^3)+(j*m^4))/5;
var x:= 1;
while x<= min([size(age_cat),size(period_lt)]) do (
var b:= a*n;
b:= b[@age_cat=@age_cat-1, @period_lt=@period_lt-1];
a:= if b=null then a else b;
x:= x+1);
a

Code description line by line:

1-2: The population table for which the projection is based on (age*follow-up year array). Population in the beginning of first 5-year time step is based on the population input data, which is summed up to derive population in 5-year age intervals. Population in age group 0-4 for the 100 year period is based on the child (0-4 years old) population projection.

3: Calculation of the annual total mortality rate (1-year age interval).

4: If mortality effects are defined to be of acute nature (i.e. ERF represents impact on daily instead of annual mortality), the population is projected only based on the total mortality risk in the BAU scenario.

5-8: If exposure is defined to change in the course of the assessment follow-up period, the exposure in 1-year time intervals based on the exposure input data given in 5-year time intervals. If the assessment follow-up period is < 100 years, the exposure level defined for the last follow-up 5-year period applies for the rest of the 100 years.

9-10: Total mortality rate is limited to be between 0 and 2

11: Calculation of the annual survival rate.

12: Calculation of the annual average survival rate for 5-year age groups.

13-15: Calculation of the average survival rate from one age group and 5-year follow-up period to the next age group and 5-year follow-up period.

16-22: The population is projected through the 100 year time period. Population at a beginning of a given age group and 5-year follow-up period is multiplied with the average 5-year-period survival rate for the age group. The result is the population of the next age group in the beginning of the following 5-year follow-up period.

Population in time, average for time step

Parameter identifier: Pop_in_time_ave

Based on the population projection which determines the population structure in the beginning of 5-year time steps, the model calculates the average number of population during each 5-year time step for the assessment follow-up period. However, if the follow-up period is only 1 year, the population structure during this year is defined based on the population input data.

var a:=Pop_in_time_beg[Period_lt=Fu_period];
var b:=(Pop_in_time_beg[@Period_lt=@Period_lt+1])[Period_lt=Fu_period];
b:= if b = null then a[Fu_period=max(Fu_period)] else b;
b:=(a+b)/2;
if followup_time=1 then a else b

Code description line by line:

1: Population in the beginning of each 5-year time step during the assessment follow-up period.

2-3: Population in the beginning of the next 5-year time step.

4: Based on these, the model calculates the average number of population within all age groups for each 5-year time step.

5: If the assessment follow-up period is 1 year, population structure is the same as in the beginning of the population projection (i.e. calculated directly from the population input data)